main.qml Example File

  /****************************************************************************
  **
  ** Copyright (C) 2015 The Qt Company Ltd.
  ** Contact: http://www.qt.io/licensing/
  **
  ** This file is part of the examples of the Qt Toolkit.
  **
  ** $QT_BEGIN_LICENSE:BSD$
  ** You may use this file under the terms of the BSD license as follows:
  **
  ** "Redistribution and use in source and binary forms, with or without
  ** modification, are permitted provided that the following conditions are
  ** met:
  **   * Redistributions of source code must retain the above copyright
  **     notice, this list of conditions and the following disclaimer.
  **   * Redistributions in binary form must reproduce the above copyright
  **     notice, this list of conditions and the following disclaimer in
  **     the documentation and/or other materials provided with the
  **     distribution.
  **   * Neither the name of The Qt Company Ltd nor the names of its
  **     contributors may be used to endorse or promote products derived
  **     from this software without specific prior written permission.
  **
  **
  ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  **
  ** $QT_END_LICENSE$
  **
  ****************************************************************************/

  import QtQuick 2.2
  import QtQuick.Controls 1.1
  import QtWebView 1.1
  import QtQuick.Layouts 1.1
  import QtQuick.Controls.Styles 1.2

  ApplicationWindow {
      property bool showProgress: webView.loading
                                  && Qt.platform.os !== "ios"
                                  && Qt.platform.os !== "winrt"
      visible: true
      x: initialX
      y: initialY
      width: initialWidth
      height: initialHeight
      title: webView.title

      toolBar: ToolBar {
          id: navigationBar
          RowLayout {
              anchors.fill: parent
              spacing: 0

              ToolButton {
                  id: backButton
                  tooltip: qsTr("Back")
                  iconSource: "images/left-32.png"
                  onClicked: webView.goBack()
                  enabled: webView.canGoBack
                  Layout.preferredWidth: navigationBar.height
                  style: ButtonStyle {
                      background: Rectangle { color: "transparent" }
                  }
              }

              ToolButton {
                  id: forwardButton
                  tooltip: qsTr("Forward")
                  iconSource: "images/right-32.png"
                  onClicked: webView.goForward()
                  enabled: webView.canGoForward
                  Layout.preferredWidth: navigationBar.height
                  style: ButtonStyle {
                      background: Rectangle { color: "transparent" }
                  }
              }

              ToolButton {
                  id: reloadButton
                  tooltip: webView.loading ? qsTr("Stop"): qsTr("Refresh")
                  iconSource: webView.loading ? "images/stop-32.png" : "images/refresh-32.png"
                  onClicked: webView.loading ? webView.stop() : webView.reload()
                  Layout.preferredWidth: navigationBar.height
                  style: ButtonStyle {
                      background: Rectangle { color: "transparent" }
                  }
              }

              Item { Layout.preferredWidth: 5 }

              TextField {
                  Layout.fillWidth: true
                  id: urlField
                  inputMethodHints: Qt.ImhUrlCharactersOnly | Qt.ImhPreferLowercase
                  text: webView.url

                  onAccepted: webView.url = utils.fromUserInput(text)

                  ProgressBar {
                      anchors.centerIn: parent
                      style: LoadProgressStyle { }
                      z: Qt.platform.os === "android" ? -1 : 1
                      visible: showProgress
                      minimumValue: 0
                      maximumValue: 100
                      value: webView.loadProgress == 100 ? 0 : webView.loadProgress
                  }
              }

              Item { Layout.preferredWidth: 5 }

              ToolButton {
                  id: goButton
                  text: qsTr("Go")
                  Layout.preferredWidth: navigationBar.height
                  onClicked: {
                      Qt.inputMethod.commit()
                      Qt.inputMethod.hide()
                      webView.url = utils.fromUserInput(urlField.text)
                  }
                  style: ButtonStyle {
                      background: Rectangle { color: "transparent" }
                  }
              }

              Item { Layout.preferredWidth: 10 }
          }
      }

      statusBar: StatusBar {
          id: statusBar
          visible: showProgress
          RowLayout {
              anchors.fill: parent
              Label { text: webView.loadProgress == 100 ? qsTr("Done") : qsTr("Loading: ") + webView.loadProgress + "%" }
          }
      }

      WebView {
          id: webView
          anchors.fill: parent
          url: initialUrl
          onLoadingChanged: {
              if (loadRequest.errorString)
                  console.error(loadRequest.errorString);
          }
      }
  }