Connect.qml Example File

  /***************************************************************************
  **
  ** Copyright (C) 2017 The Qt Company Ltd.
  ** Contact: http://www.qt.io/licensing/
  **
  ** This file is part of the examples of the QtBluetooth module of the Qt Toolkit.
  **
  ** $QT_BEGIN_LICENSE:BSD$
  ** You may use this file under the terms of the BSD license as follows:
  **
  ** "Redistribution and use in source and binary forms, with or without
  ** modification, are permitted provided that the following conditions are
  ** met:
  **   * Redistributions of source code must retain the above copyright
  **     notice, this list of conditions and the following disclaimer.
  **   * Redistributions in binary form must reproduce the above copyright
  **     notice, this list of conditions and the following disclaimer in
  **     the documentation and/or other materials provided with the
  **     distribution.
  **   * Neither the name of The Qt Company Ltd nor the names of its
  **     contributors may be used to endorse or promote products derived
  **     from this software without specific prior written permission.
  **
  **
  ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  **
  ** $QT_END_LICENSE$
  **
  ****************************************************************************/

  import QtQuick 2.5
  import Shared 1.0

  GamePage {

      errorMessage: deviceFinder.error
      infoMessage: deviceFinder.info

      Rectangle {
          id: viewContainer
          anchors.top: parent.top
          anchors.bottom:
              // only BlueZ platform has address type selection
              connectionHandler.requiresAddressType ? addressTypeButton.top : searchButton.top
          anchors.topMargin: GameSettings.fieldMargin + messageHeight
          anchors.bottomMargin: GameSettings.fieldMargin
          anchors.horizontalCenter: parent.horizontalCenter
          width: parent.width - GameSettings.fieldMargin*2
          color: GameSettings.viewColor
          radius: GameSettings.buttonRadius

          Text {
              id: title
              width: parent.width
              height: GameSettings.fieldHeight
              horizontalAlignment: Text.AlignHCenter
              verticalAlignment: Text.AlignVCenter
              color: GameSettings.textColor
              font.pixelSize: GameSettings.mediumFontSize
              text: qsTr("FOUND DEVICES")

              BottomLine {
                  height: 1;
                  width: parent.width
                  color: "#898989"
              }
          }

          ListView {
              id: devices
              anchors.left: parent.left
              anchors.right: parent.right
              anchors.bottom: parent.bottom
              anchors.top: title.bottom
              model: deviceFinder.devices
              clip: true

              delegate: Rectangle {
                  id: box
                  height:GameSettings.fieldHeight * 1.2
                  width: parent.width
                  color: index % 2 === 0 ? GameSettings.delegate1Color : GameSettings.delegate2Color

                  MouseArea {
                  anchors.fill: parent
                      onClicked: {
                          deviceFinder.connectToService(modelData.deviceAddress);
                          app.showPage("Measure.qml")
                      }
                  }

                  Text {
                      id: device
                      font.pixelSize: GameSettings.smallFontSize
                      text: modelData.deviceName
                      anchors.top: parent.top
                      anchors.topMargin: parent.height * 0.1
                      anchors.leftMargin: parent.height * 0.1
                      anchors.left: parent.left
                      color: GameSettings.textColor
                  }

                  Text {
                      id: deviceAddress
                      font.pixelSize: GameSettings.smallFontSize
                      text: modelData.deviceAddress
                      anchors.bottom: parent.bottom
                      anchors.bottomMargin: parent.height * 0.1
                      anchors.rightMargin: parent.height * 0.1
                      anchors.right: parent.right
                      color: Qt.darker(GameSettings.textColor)
                  }
              }
          }
      }

      GameButton {
          id: addressTypeButton
          anchors.horizontalCenter: parent.horizontalCenter
          anchors.bottom: searchButton.top
          anchors.bottomMargin: GameSettings.fieldMargin*0.5
          width: viewContainer.width
          height: GameSettings.fieldHeight
          visible: connectionHandler.requiresAddressType // only required on BlueZ
          state: "public"
          onClicked: state == "public" ? state = "random" : state = "public"

          states: [
              State {
                  name: "public"
                  PropertyChanges { target: addressTypeText; text: qsTr("Public Address") }
                  PropertyChanges { target: deviceHandler; addressType: AddressType.PublicAddress }
              },
              State {
                  name: "random"
                  PropertyChanges { target: addressTypeText; text: qsTr("Random Address") }
                  PropertyChanges { target: deviceHandler; addressType: AddressType.RandomAddress }
              }
          ]

          Text {
              id: addressTypeText
              anchors.centerIn: parent
              font.pixelSize: GameSettings.tinyFontSize
              color: GameSettings.textColor
          }
      }

      GameButton {
          id: searchButton
          anchors.horizontalCenter: parent.horizontalCenter
          anchors.bottom: parent.bottom
          anchors.bottomMargin: GameSettings.fieldMargin
          width: viewContainer.width
          height: GameSettings.fieldHeight
          enabled: !deviceFinder.scanning
          onClicked: deviceFinder.startSearch()

          Text {
              anchors.centerIn: parent
              font.pixelSize: GameSettings.tinyFontSize
              text: qsTr("START SEARCH")
              color: searchButton.enabled ? GameSettings.textColor : GameSettings.disabledTextColor
          }
      }
  }